# Maintainer: Allan McRae <allan@archlinux.org>
# Contributor: judd <jvinet@zeroflux.org>

pkgname=ncurses
pkgver=5.8
pkgrel=1
pkgdesc="System V Release 4.0 curses emulation library"
arch=('i686' 'x86_64')
url="http://www.gnu.org/software/ncurses/"
license=('MIT')
groups=('base')
depends=('glibc')
source=("ftp://ftp.gnu.org/pub/gnu/${pkgname}/${pkgname}-${pkgver}.tar.gz")
md5sums=('20ed3fa7599937f0ca268d9088837a64')

build() {
  cd ${srcdir}/${pkgname}-${pkgver}
  
  ./configure \
    --prefix=/usr \
    --mandir=/usr/share/man \
    --with-shared \
    --with-normal \
    --without-debug \
    --without-ada \
    --with-install-prefix=${pkgdir} \
    --enable-widec
  
  make
  
  ############################################################################# 
  # Build libncurses.so.5 for external binary support 
  cp -r ${srcdir}/${pkgname}-${pkgver} ${srcdir}/${pkgname}-${pkgver}-libncurses.so.5
  cd ${srcdir}/${pkgname}-${pkgver}-libncurses.so.5
  [ $CARCH = "x86_64" ] && CONFIGFLAG="--with-chtype=long"
  ./configure \
    --prefix=/usr \
    --with-shared \
    --with-normal \
    --without-debug \
    --without-ada \
    --with-install-prefix=${pkgdir} \
    $CONFIGFLAG
  
  make
}

package() {
  cd ${srcdir}/${pkgname}-${pkgver}
  
  make install
  
  # move libraries needed for boot to /lib (we call tput in initscripts)
  install -dm755 ${pkgdir}/lib
  mv ${pkgdir}/usr/lib/libncursesw.so.5* ${pkgdir}/lib
  ln -sf ../../lib/libncursesw.so.5 ${pkgdir}/usr/lib/libncursesw.so

  # Fool packages looking to link to non-wide-character ncurses libraries
  for lib in curses ncurses form panel menu ; do 
    rm -f ${pkgdir}/usr/lib/lib${lib}.so
    echo "INPUT(-l${lib}w)" >${pkgdir}/usr/lib/lib${lib}.so
    ln -sf lib${lib}w.a ${pkgdir}/usr/lib/lib${lib}.a
  done
  ln -sf libncurses++w.a ${pkgdir}/usr/lib/libncurses++.a
  
  # install tput to /bin
  install -dm755 ${pkgdir}/bin/
  mv ${pkgdir}/usr/bin/tput ${pkgdir}/bin/tput
  
  # Some packages look for -lcurses during build
  rm -f ${pkgdir}/usr/lib/libcursesw.so
  echo "INPUT(-lncursesw)" >${pkgdir}/usr/lib/libcursesw.so
  ln -sf libncurses.so ${pkgdir}/usr/lib/libcurses.so
  ln -sf libncursesw.a ${pkgdir}/usr/lib/libcursesw.a
  ln -sf libncurses.a ${pkgdir}/usr/lib/libcurses.a
 
  ############################################################################# 
  # Install libncurses.so.5 for external binary support 
  cd ${srcdir}/${pkgname}-${pkgver}-libncurses.so.5
  install -Dm755 lib/libncurses.so.${pkgver} ${pkgdir}/usr/lib/libncurses.so.${pkgver}
  ln -sf libncurses.so.${pkgver} ${pkgdir}/usr/lib/libncurses.so.5
  
  # install license, rip it from the readme
  cd ${srcdir}/${pkgname}-${pkgver}
  install -dm755 ${pkgdir}/usr/share/licenses/$pkgname
  grep -B 100 '$Id' README > ${pkgdir}/usr/share/licenses/${pkgname}/license.txt
}

# vim:set ts=2 sw=2 et:
