# Maintainer: Eric Belanger <eric@archlinux.org>
# Contributor: Lucien Immink <l.immink@student.fnt.hvu.nl>

pkgname=curl
pkgver=7.21.4
pkgrel=1
pkgdesc="url retrival utility and library"
arch=('i686' 'x86_64')
url="http://curl.haxx.se"
license=('MIT')
depends=('zlib' 'openssl>=0.9.8b' 'bash' 'ca-certificates')
options=('!libtool')
source=("http://curl.haxx.se/download/$pkgname-$pkgver.tar.bz2")
md5sums=('e2dd20c88a7d01c745af9d788545ab2a')

build() {
  cd $srcdir/$pkgname-$pkgver

  # Thanks Debian and Gentoo =)
  ./configure \
    --with-random=/dev/urandom \
    --prefix=/usr \
    --mandir=/usr/share/man \
    --disable-dependency-tracking \
    --enable-ipv6 \
    --disable-ldaps \
    --disable-ldap \
    --enable-manual \
    --enable-versioned-symbols \
    --with-ca-path=/etc/ssl/certs \
    --without-libidn || return 1
  
  make || return 1
}

package() {
  cd $srcdir/$pkgname-$pkgver

  make DESTDIR=${pkgdir} install || return 1

  # install license
  install -Dm644 COPYING $pkgdir/usr/share/licenses/$pkgname/COPYING || return 1

  install -Dm644 docs/libcurl/libcurl.m4 $pkgdir/usr/share/aclocal/libcurl.m4 || return 1
}

# vim:set ts=2 sw=2 et:
