# Maintainer: kevin <kevin@archlinux.org>
# Contributor: mario <mario_vazq@hotmail.com>

pkgname=dnsutils
# Use a period and not a hyphen before the patch level for proper versioning.
pkgver=9.7.3
_pkgver=9.7.3
pkgrel=2
pkgdesc="Various DNS utilities - dig host nslookup nsupdate"
arch=('i686' 'x86_64')
url="https://www.isc.org/software/bind"
license=('custom:ISC')
depends=('openssl>=0.9.8h')
replaces=('bind-tools' 'host')
options=('makeflags')
source=("http://ftp.isc.org/isc/bind9/${_pkgver}/bind-${_pkgver}.tar.gz"
        'tools-only.patch')
md5sums=('207477c4cf95f2db5be0ded8a22669e0'
         'be0558f70ed81d90e68e6b6003ba12ed')

build() {
  cd ${srcdir}/bind-${_pkgver}
  
  patch -Np1 -i $srcdir/tools-only.patch || return 1
  
  ./configure \
    --prefix=/usr \
    --sysconfdir=/etc \
    --localstatedir=/var \
		--with-openssl=yes \
    --disable-linux-caps \
    --without-libxml2 || return 1
  
  make || return 1
}

package() {
  cd $srcdir/bind-${_pkgver}/bin || return 1
  
  make DESTDIR="${pkgdir}" install || return 1

  # install license
  install -Dm644 ../COPYRIGHT $pkgdir/usr/share/licenses/$pkgname/LICENSE || return 1
}

# vim:set ts=2 sw=2 et:
