# Maintainer: 
# Contributor: Judd Vinet <jvinet@zeroflux.org>

pkgname=libldap
pkgver=2.4.19
pkgrel=1	
pkgdesc="Lightweight Directory Access Protocol (LDAP) client libraries"
arch=('i686' 'x86_64')
license=('custom')
url="http://www.openldap.org/"
backup=('etc/openldap/ldap.conf')
depends=('libsasl' 'openssl>=0.9.8f')
makedepends=('tcp_wrappers')
options=('!libtool')
source=("ftp://ftp.openldap.org/pub/OpenLDAP/openldap-release/openldap-${pkgver}.tgz"
        'ntlm.patch')
md5sums=('4a6dab2711fcf141f19bb680bc335887'
         'dfa9eb6f2fd9d0a3dab0e1860923489e')

build() {
  cd ${srcdir}/openldap-${pkgver}
  
  patch -Np1 -i ${srcdir}/ntlm.patch || return 1
  
  ./configure \
    --prefix=/usr \
    --libexecdir=/usr/sbin \
    --sysconfdir=/etc \
    --mandir=/usr/share/man \
    --localstatedir=/var/lib/openldap \
    --enable-crypt \
    --enable-dynamic \
    --with-threads \
    --enable-wrappers \
    --enable-spasswd \
    --with-cyrus-sasl \
    --disable-bdb \
    --disable-hdb || return 1
  
  cd ${srcdir}/openldap-${pkgver}/include || return 1
  make || return 1
  
  cd ${srcdir}/openldap-${pkgver}/libraries || return 1
  make depend || return 1
  make || return 1
  
  cd ${srcdir}/openldap-${pkgver}/doc/man/man3 || return 1
  make || return 1
  
  cd ${srcdir}/openldap-${pkgver}/doc/man/man5 || return 1
  make || return 1
}

package() {
  cd ${srcdir}/openldap-${pkgver}/include || return 1
  make DESTDIR=${pkgdir} install || return 1
  
  cd ${srcdir}/openldap-${pkgver}/libraries || return 1
  make DESTDIR=${pkgdir} install || return 1
  
  cd ${srcdir}/openldap-${pkgver}/doc/man/man3 || return 1
  make DESTDIR=${pkgdir} install || return 1
  
  cd ${srcdir}/openldap-${pkgver}/doc/man/man5 || return 1
  install -Dm644 ldap.conf.5.tmp ${pkgdir}/usr/share/man/man5/ldap.conf.5 || return 1
  
  # get rid of duplicate default conf files
  rm ${pkgdir}/etc/openldap/*.default || return 1
  
  ln -sf liblber.so ${pkgdir}/usr/lib/liblber.so.2 || return 1
  ln -sf libldap.so ${pkgdir}/usr/lib/libldap.so.2 || return 1
  
  install -Dm644 ${srcdir}/openldap-${pkgver}/LICENSE ${pkgdir}/usr/share/licenses/$pkgname/LICENSE || return 1
}

# vim:set ts=2 sw=2 et:
