# Maintainer: Phillip Smith <fukawi2@archserver.org>
# Contributor: Mark van Dijk <mark@voidzero.net>

pkgname=vixie-cron
arch=('i686' 'x86_64')
pkgver=4.1
pkgrel=2
gentoo_patchver=4
license=("GPL")
pkgdesc="Paul Vixie's cron daemon, a fully featured crond implementation"
url="ftp://ftp.isc.org/isc/cron/"
backup=('etc/crontab')
depends=('glibc')
provides=('cron' 'dcron')
gentoo_mirror='ftp://ftp.snt.utwente.nl/pub/linux/gentoo/distfiles/'
source=("$gentoo_mirror/${pkgname}-${pkgver}.tar.bz2"
        "$gentoo_mirror/${pkgname}-${pkgver}-gentoo-r${gentoo_patchver}.patch.bz2"
        'crond' 'cronrunparts' 'crontab') 
md5sums=('09dc04f9879684d27c64c910174a9536'
         'c674b03c6e76798b1c74f6070df167cc'
         '50eb94e68a907a6165910fe9deba76d1'
         '00ede56aadf073c839e600033fbd6cb4'
         'b8b1d315dd2f92528dc6fa7ae8cef32b')

build() {
  cd $srcdir/$pkgname-$pkgver
  
  patch -p1 < $srcdir/$pkgname-$pkgver-gentoo-r$gentoo_patchver.patch
  
  make all
}

package() {
  cd $srcdir/$pkgname-$pkgver
  
  mkdir -p $pkgdir/usr/{sbin,bin}
  mkdir -p $pkgdir/usr/man/{man8,man1,man5}
  mkdir -p $pkgdir/etc/rc.d
  mkdir -p $pkgdir/etc/cron.{d,hourly,daily,weekly,monthly}
  mkdir -p $pkgdir/var/spool/cron
  
  install -m 0111 cron $pkgdir/usr/sbin/cron
  install -m 4111 crontab $pkgdir/usr/bin/crontab
  install -m 0755 $srcdir/cronrunparts $pkgdir/usr/bin/cronrunparts

  cp crontab.1  $pkgdir/usr/man/man1
  cp cron.8     $pkgdir/usr/man/man8
  cp crontab.5  $pkgdir/usr/man/man5
  
  install -m 755 -o root $srcdir/crond $pkgdir/etc/rc.d/
  install $srcdir/crontab -m 600 -o root $pkgdir/etc
}

# vim:set ts=2 sw=2 et:
